Monthly Archives: March 2013

I am back after a short break. Let’s continue where we left off. Today I will talk about object oriented Lotusscript. We looked at functions in part 3 of this series, and while functions are very useful, you should consider building objects instead.

So why would you use classes? The short answer is that they are much more powerful and also much easier to maintain. The code is usually shorter and I get a better overview. It is modular and can easily be moved to other applications. It is easy to maintain and add functionality. And the calling code can be very compact and easy to understand as well.

You are already using objects/classes today, when you are writing Lotusscript code. The DOM (Domino Object Model) are made up of classes that let you access different Domino objects, like sessions, databases, views, documents, etc. You already know how to call and use classes, now we will look at creating your own. It is much easier than you probably think.

About 2 years ago, I wrote two articles about object oriented Lotusscript, but the code samples were scrambled when I moved my blog to WordPress. You can find the old articles here and here. But the article you are currently reading will be look at a more basic class, and explain more of the code.

I have posted several classes here on my blog in the past, doing different things:
Get latitude and longitude for an address – Win32 only
Mail Merge/Form Letters in Lotusscript
Mail Notification Class
Class for File Functions
HTML Retrieval Class – Win32 only
Accessing Windows Clipboard – Win32 only

Take a look at those article and you should get an understanding of how to write a class..

Your First Class

Let’s start with a very simple class. It will contain some math functions. We will start with just one, used to add two values together.

Option Public
Option Declare

Class MathClass
    Public value1 As Integer
    Public value2 As Integer

    %REM
        Sub New()
        Description: Constructor for the class
    %END REM
    Public Sub New()
        '*** We will add code here later
    End Sub

    %REM
        Function Add()
        Description: Adding value1 and value2 and retur result
    %END REM
    Public Function Add() As Integer
        Add = value1 + value2
        End Function
End Class

And this is how you use the class:

Sub Initialize
    Dim math As MathClass
    '*** Create new instance of MathClass
    Set math = New MathClass()
    '*** Set the two values in the class
    math.value1 = 4
    math.value2 = 6
    '*** Display the result of the Add() function
    MsgBox math.Add()
End Sub

Easy, wasn’t it? However, we can expand a little on this. Instead of assigning the variables value1 and value2 after the math object is created, we can pass the values to the object at create time:

Option Public
Option Declare

Class MathClass
    Public value1 As Integer
    Public value2 As Integer

    %REM
        Sub New()
        Description: Constructor for the class, taking two integers as arguments
    %END REM
    Public Sub New(arg1 As Integer, arg2 As Integer)
        value1 = arg1
        value2 = arg2
    End Sub

    %REM
        Function Add()
        Description: Adding value1 and value2 and return result
    %END REM
    Public Function Add() As Integer
        Add = value1 + value2
    End Function
End Class

And here is the updated code to use the class:

Sub Initialize
    Dim math As MathClass
    '*** Create new instance of MathClass
    Set math = New MathClass(4,6)
    '*** Display the result of the Add() function
    MsgBox math.Add()
End Sub

We can now easily add more functions to the class, for subtraction, multiplication, etc.

Get/Set properties of your class

Often it is a good idea to check the values you pass to the class. The easiest way is to use the Set properties. You use the corresponding Get property to read values from the class. In this example, we will check if the value is greater than 100, and if so we will reduce the value by 100 before storing it in the rivate variable used inside the class.

Option Public
Option Declare

Class MathClass
    Private p_value1 As Integer
    Private p_value2 As Integer

    %REM
        Sub New()
        Description: Constructor for the class
    %END REM
    Public Sub New()

    End Sub

    %REM
        Property Set value1
        Description: Set value1 and subtract 100 if needed
    %END REM
    Property Set value1 
        If value1>100 Then
            p_value1 = value1 - 100
        Else    
            p_value1 = value1
        End If
    End Property

    %REM
        Property Set value2
        Description: Set value2 and subtract 100 if needed
    %END REM
    Property Set value2 
        If value2>100 Then
            p_value2 = value2 - 100
        Else    
            p_value2 = value2
        End If
    End Property

    %REM
        Function Add()
        Description: Adding value1 and value2 and return result
    %END REM
    Public Function Add() As Integer
        Add = p_value1 + p_value2
    End Function
End Class

We call the class exactly like in our first example. But remember that we reduce the number by 100 if it is larger than 100. The output of this code is identical to the previous examples:

Sub Initialize
    Dim math As MathClass

    '*** Create new instance of MathClass
    Set math = New MathClass()
    '*** Set properties of the object
    math.value1 = 4
    math.value2 = 106
    '*** Display the result of the Add() function
    MsgBox math.Add()
End Sub

Let’s say we want to add a function that subtract the first value from the second value. We then just add a Subtract() function to the class:

    %REM
        Function Subtract()
        Description: Subtracting value1 from value2 and return result
    %END REM
    Public Function Subtract() As Integer
        Subtract = p_value2 - p_value1
    End Function

Now you have the foundation of object oriented Lotusscript. Go forth and conquer!