TexasSwede
texasswede@gmail.com
  • About this blog
  • My Website
  • My Resume
  • XML Export Tool
  • Photos

Agent Logging – Budget Style

Posted on November 10, 2010 by Karl-Henry Martinsson Posted in IBM/Lotus, Lotusscript, Notes/Domino, Programming

At my work, we had several issues/needs related to agents in different Domino databases. I tried to come up with a quick and lean solution, that gave us the functionality we needed, nothing more and nothing less. Yes, I am aware of Julian Robichaux’s excellent OpenLog. But we had some needs that I did not feel were addressed in that project.

What I wanted was a database where the agents could be documented, and also where the log data was stored. So I created a Agent Log database where one document is stored per agent. The form let me document the actions of the agent, as well as what server it is running on, in what database, when it is triggered, etc. When the document is opened, I also read the last time the agent was run and if the agent is enabled or not.

This is a sample document for an agent. It is scheduled to run at 11am every day:

AgentLog_Doc

 

This is what the actual database looks like.

AgentLog

I plan to release the database on OpenNTF.org when I get the time.

 

Nothing complicated this far. The next step was to create a small script library, doing the actual logging. I created a script library called Class.AgentLog with the following code:

Public Const THREAD_TICKS=6
Public Const THREAD_TICKS_PER_SEC=7

Class AgentLog
	Private session As NotesSession
	Private logdb As NotesDatabase
	Private agentdoc As NotesDocument   ' Main doc in Agent Log db
	Private logdoc As NotesDocument
	Private running As Integer
	Private tstart As Long              ' Ticks at start
	Private tend As Long                ' Ticks at end
	Private tps As Long                 ' Ticks per second (system dependant)
	
	Public Sub New( agentname As String )
		Dim view As NotesView
		Dim key As String
		running = True
		tstart = GetThreadInfo( THREAD_TICKS )
		tps = GetThreadInfo( THREAD_TICKS_PER_SEC )
		Set session = New NotesSession
		Set logdb = New NotesDatabase( session.CurrentDatabase.Server, "IT/AgentLog.nsf" )
		Set view = logdb.GetView( "(LookupAgent)" )
		If agentname = "" Then
			agentname = session.CurrentAgent.Name
		End If
		key = session.CurrentDatabase.FilePath & "~" & agentname
		Set agentdoc = view.GetDocumentByKey( key )
		If agentdoc Is Nothing Then
			Print "AgentLog: Failed to locate agent document for " & agentname & "."
			Exit Sub
		End If
		Set logdoc = New NotesDocument( logdb )
		logdoc.Form = "LogItem"
		Call logdoc.MakeResponse( agentdoc )
		Call logdoc.ReplaceItemValue("AgentName", agentname )
		Call logdoc.ReplaceItemValue("StartTime", Now() )
		If session.IsOnServer = True Then
			Call logdoc.ReplaceItemValue("RunBy", session.CurrentDatabase.Server )
		Else
			Call logdoc.ReplaceItemValue("RunBy", session.CommonUserName )
		End If
	End Sub
	
	Public Sub Finish()
		running = False
	End Sub
	
	Public Sub Terminate()
		Dim seconds As Integer
		If logdoc Is Nothing Then
			Exit Sub
		End If
		tend = GetThreadInfo( THREAD_TICKS )
		seconds = (tend - tstart) / tps
		Call logdoc.ReplaceItemValue("EndTime", Now() )
		Call logdoc.ReplaceItemValue("Seconds", seconds )
		If running = True Then ' Check if not terminated gracefully
			Call logdoc.ReplaceItemValue("Terminated", "Yes" )
		End If
		Call logdoc.Save(True,True)
	End Sub

End Class

All code goes in the (Declarations) section of the script library.
There are a few things to notice. I actually make each log item a child (response) document to the main document. By doing this, I can easily later create reports for each agent about all the times it was executed, etc.
When the object is instantiated, a blank string is normally passed. This will set the agent name variable to the actual agent name. The agent name is listed in the agent log document. If for some reason you want to use a different agent name in the document (e.g. the agent is a manually triggered agent called AdminUpdateSelectedDocuments and you want it listed just as UpdateSelectedDocuments).

 

The only thing left now is to update every agent you want to log as follows:

In the (Options) section:

Use "Class.AgentLog"

In the (Declarations) section:

Dim agent As AgentLog

In the Initialize event, I put one line at the beginning and one right at the end. The first line instantiate the agent log object and. set a flag indicating that the agent is running. The second line will clear that flag, so the final function knows that the agent ended gracefully.

Sub Initialize
 Set agent = New AgentLog("")
 ' *** Do stuff here
 Call agent.Finish()
End Sub

The last thing is to add one line to the Terminate event. This line is where the logging is actually done. If the flag running is set, we know the agent was terminated before it actually reached the end.

Sub Terminate
 Call agent.Terminate()
End Sub

Happy logging!

« Paintings from Photos
My Favorite Free Icon Set »

Leave a comment Cancel reply

Your email address will not be published. Required fields are marked *

This site uses Akismet to reduce spam. Learn how your comment data is processed.

HCL Ambassador 2020

HCL Ambassador 2020

IBM Champion 2014-2020

Stack Exchange

profile for Karl-Henry Martinsson on Stack Exchange, a network of free, community-driven Q&A sites

Notes/Domino Links

  • Planet Lotus Planet Lotus
  • IBM dW Forums IBM dW Forums
  • StackOverflow StackOverflow

Recent Posts

  • Notes and Domino v12 is here!
  • NTF Needs Your Help
  • Helpful Tools – Ytria EZ Suite (part 2)
  • Busy, busy – But wait: There is help!
  • Semantic UI – An alternative to Bootstrap?

Recent Comments

  • Lotus Script Multi-thread Message Box [SOLVED] – Wanted Solution on ProgressBar class for Lotusscript
  • Viet Nguyen on Keep up with COVID-19 though Domino!
  • Viet Nguyen on Keep up with COVID-19 though Domino!
  • Mark Sullivan on Looking for a HP calculator? Look no further!
  • Lynn He on About This Blog

My Pages

  • How to write better code in Notes

Archives

  • June 2021 (1)
  • April 2021 (2)
  • March 2021 (1)
  • August 2020 (3)
  • July 2020 (2)
  • April 2020 (2)
  • March 2020 (1)
  • December 2019 (2)
  • September 2019 (1)
  • August 2019 (2)
  • July 2019 (2)
  • June 2019 (3)
  • April 2019 (2)
  • December 2018 (1)
  • November 2018 (1)
  • October 2018 (5)
  • August 2018 (2)
  • July 2018 (3)
  • June 2018 (2)
  • May 2018 (1)
  • April 2018 (2)
  • March 2018 (1)
  • February 2018 (2)
  • January 2018 (4)
  • December 2017 (3)
  • November 2017 (2)
  • October 2017 (2)
  • September 2017 (1)
  • August 2017 (2)
  • July 2017 (6)
  • May 2017 (4)
  • February 2017 (1)
  • January 2017 (2)
  • December 2016 (2)
  • October 2016 (3)
  • September 2016 (4)
  • August 2016 (1)
  • July 2016 (2)
  • June 2016 (2)
  • May 2016 (3)
  • April 2016 (1)
  • March 2016 (4)
  • February 2016 (2)
  • January 2016 (4)
  • December 2015 (3)
  • November 2015 (2)
  • October 2015 (1)
  • September 2015 (2)
  • August 2015 (1)
  • July 2015 (5)
  • June 2015 (2)
  • April 2015 (2)
  • March 2015 (3)
  • February 2015 (2)
  • January 2015 (10)
  • December 2014 (1)
  • November 2014 (3)
  • October 2014 (3)
  • September 2014 (13)
  • August 2014 (6)
  • July 2014 (5)
  • May 2014 (3)
  • March 2014 (2)
  • January 2014 (10)
  • December 2013 (5)
  • November 2013 (2)
  • October 2013 (5)
  • September 2013 (4)
  • August 2013 (7)
  • July 2013 (3)
  • June 2013 (1)
  • May 2013 (4)
  • April 2013 (7)
  • March 2013 (8)
  • February 2013 (9)
  • January 2013 (5)
  • December 2012 (7)
  • November 2012 (13)
  • October 2012 (10)
  • September 2012 (2)
  • August 2012 (1)
  • July 2012 (1)
  • June 2012 (3)
  • May 2012 (11)
  • April 2012 (3)
  • March 2012 (2)
  • February 2012 (5)
  • January 2012 (14)
  • December 2011 (4)
  • November 2011 (7)
  • October 2011 (8)
  • August 2011 (4)
  • July 2011 (1)
  • June 2011 (2)
  • May 2011 (4)
  • April 2011 (4)
  • March 2011 (7)
  • February 2011 (5)
  • January 2011 (17)
  • December 2010 (9)
  • November 2010 (21)
  • October 2010 (4)
  • September 2010 (2)
  • July 2010 (3)
  • June 2010 (2)
  • May 2010 (3)
  • April 2010 (8)
  • March 2010 (3)
  • January 2010 (5)
  • November 2009 (4)
  • October 2009 (7)
  • September 2009 (1)
  • August 2009 (7)
  • July 2009 (1)
  • June 2009 (4)
  • May 2009 (1)
  • April 2009 (1)
  • February 2009 (1)
  • January 2009 (3)
  • December 2008 (1)
  • November 2008 (1)
  • October 2008 (7)
  • September 2008 (7)
  • August 2008 (6)
  • July 2008 (5)
  • June 2008 (2)
  • May 2008 (5)
  • April 2008 (4)
  • March 2008 (11)
  • February 2008 (10)
  • January 2008 (8)

Categories

  • AppDev (9)
  • Blogging (11)
    • WordPress (5)
  • Design (5)
    • Graphics (1)
    • UI/UX (2)
  • Featured (5)
  • Financial (2)
  • Food (5)
    • Baking (3)
    • Cooking (3)
  • Generic (11)
  • History (5)
  • Hobbies (10)
    • LEGO (4)
    • Photography (4)
  • Humor (1)
  • IBM/Lotus (175)
    • #Domino2025 (14)
    • #DominoForever (8)
    • #IBMChampion (46)
    • Administration (7)
    • Cloud (7)
    • CollabSphere (8)
    • Community (47)
    • Connect (33)
    • ConnectED (12)
    • Connections (3)
    • HCL (12)
    • HCL Master (1)
    • IBM Think (1)
    • Lotusphere (46)
    • MWLUG (25)
    • Notes/Domino (97)
      • Domino 11 (7)
    • Sametime (8)
    • Verse (14)
    • Volt (2)
    • Watson (6)
  • Life (8)
  • Microsoft (7)
    • .NET (2)
    • C# (1)
    • Visual Studio (1)
  • Movies (3)
  • Old Blog Post (259)
  • Personal (23)
  • Programming (83)
    • App Modernization (11)
    • Formula (4)
    • Lotusscript (46)
    • NetSuite (4)
      • SuiteScript (3)
    • node.js (4)
    • XPages (4)
  • Reviews (9)
  • Sci-Fi (4)
  • Software (24)
    • Flight Simulator (2)
    • Games (4)
    • Open Source (2)
    • Utilities (6)
  • Technology (37)
    • Aviation (3)
    • Calculators (2)
    • Computers (6)
    • Gadgets (7)
    • Mobile Phones (7)
    • Science (3)
    • Tablets (2)
  • Travel (6)
    • Texas (2)
    • United States (1)
  • Uncategorized (15)
  • Web Development (50)
    • Frameworks (23)
      • Bootstrap (14)
    • HTML/CSS (12)
    • Javascript (32)
      • jQuery (23)

Administration

  • Log in
  • Entries feed
  • Comments feed
  • WordPress.org

Tracking

Creeper
MediaCreeper
  • Family Pictures
© TexasSwede 2008-2014