Category Archives: Lotusscript

My presentation at MWLUG

Posted on by Posted in #IBMChampion, Community, IBM/Lotus, Javascript, jQuery, Lotusscript, MWLUG, Notes/Domino, Programming, Uncategorized, Web Development Leave a comment

Tomorrow, August 8, you are welcome to attend my presentation “Elementary!” at MWLUG 2017. In about 45 minutes I will show how to easily incorporate Watson functionality in your own applications, both on the web and in your Notes client applications.

I will be using Node-RED and IBM BlueMix to do this, and I think many will be surprised how easy it is, and how little code is needed. For example I will implement translation from English to Spanish with two (2) lines of server side code. To call this from the web you just need another handful of lines.

I hope to see you tomorrow at 5pm!

IBM Connect 2017 – I will be speaking in San Francisco

Posted on by Posted in #IBMChampion, Connect, IBM/Lotus, Javascript, jQuery, Lotusscript, Notes/Domino, Programming, Web Development 1 Comment

I will be speaking at IBM Connect in San Francisco now in February. Rob Novak has resurrected “The Great Code Giveaway” and asked me to present it together with him. Who would turn down that opportunity? So some time between February 21 and 23 you can see Rob and me on stage at Moscone West. The exact time and location has not been announced yet.

I hope to see you in San Francisco and that you will find our presentation and code useful!

Updated MailNotification class – Now with HTML email support and web links

Posted on by Posted in IBM/Lotus, Lotusscript, Notes/Domino, Programming 2 Comments

I have updated my MailNotification class with some additional functionality I needed at work. Since our mail system now is Outlook/Exchange, and therefore the Notes doc links don’t work anymore, I am in the process of converting all my email notifications into HTML email. The doc links are now made into HTML links, pointing to a notes:// or http:// address.

I simply added a new class, HTMLmail. It is based on the old NotesMail class, but I override a few functions that are different. This makes it very easy to update the emails I am generating in my Lotusscript agents, in most cases I only have to replace NotesMail with HTMLmail in the declaration and instantiation:

Dim maildoc As HTMLMail
Set maildoc = New HTMLMail()

When I had doc links in the email I also had to modify the code where I generate it. The method takes three arguments: the NotesDocument to link to, the Alt/Title attribute for the link (to be displayed when hovering over the link) and the text of the link:

Call maildoc.AppendDocLink(doc,"Click to open",doc.ClaimNumber(0))

In order to generate the links I created a Link class, where you can set what protocol you want to use (“notes” or “http”) you want the link to use, you can change the port from the default of 80, and you can even force the link to point to a different server. I use this class in the AppendDocLink method in the HTMLmail class.

Here is a short code sample, it is just a function to create a mail notification for an insurance claim. The claim document is passed to the function and a mail is sent to the adjuster and his/her manager.

Sub SendNotification(doc as NotesDocument)
	'*** Create a new object and set the sender, recipients and subject
	Set maildoc = New HTMLMail()
	maildoc.Principal = |"System Notification" <noreply@example.com>|
	Call maildoc.AddMailTo(doc.GetItemvalue("Adjuster")(0))
	Call maildoc.AddMailCC(GetManagerName(doc.GetItemValue("Adjuster")(0)))
	maildoc.Subject = "30 DAY ALERT - " & doc.GetItemValue("ClaimNumber")(0)
	'*** Build body content, including a link to the document
	Call maildoc.AppendText("Claim number ")
	Call maildoc.AppendDocLink(doc,"Click to open",doc.GetItemValue("ClaimNumber")(0))
	Call maildoc.AppendText(" was received on ")
	Call maildoc.AppendText(Format$(doc.GetItemValue("Received_Date")(0),"mm/dd/yyyy") & ". ")
	Call maildoc.AppendText("This claim has been opened for 30 days. ")
	Call maildoc.AppendText("Please confirm all appropriate actions has been performed.")
	Call maildoc.AddNewLine(2)
	'*** Add no-reply notification to the end and send the email
	maildoc.NoReply = True   
	Call maildoc.Send()
	'*** Flag the NotesDocument as processed and save it to avoid duplicate notifications
	doc.Warning30daySent = "Yes"
	Call doc.Save(True,True)
End Sub

That’s pretty much it.  Enjoy the code, and as usual I do not guarantee anything. Use on your own risk, as always. If you like this code and use it, let me know.

Option Public
Option Declare

Class NotesMail
	Public maildoc As NotesDocument 
	Public body As NotesRichTextItem
	Private p_subject As String
	Private p_sendto List As String
	Private p_copyto List As String
	Private p_blindcopyto List As String
	Private p_principal As String
	Public NoReply As Boolean 
	Public mailbox As NotesDatabase
	
	Public Sub New()
		Dim session As New NotesSession
		Dim mailservername As String
		' We must use mail.box on current server.
		mailservername = session.Currentdatabase.Server
		' Using mail.box directly is unsupported, but is the
		' only way to make the mail look like it is actually
		' sent from another address, in our case the principal.
		Set mailbox = New NotesDatabase(mailservername,"mail.box")
		If mailbox.Isopen = False Then
			Print "mail.box on " & mailservername & " could not be opened"
			Exit Sub
		End If
		Set me.maildoc = New NotesDocument(mailbox)
		Call me.maildoc.ReplaceItemValue("Form","Memo")
		'Set me.body = New NotesRichTextItem(maildoc,"Body")
		Call CreateBody()
		me.p_subject = ""
		me.p_principal = ""
		' Empty lists for addresses
		Erase me.p_sendto
		Erase me.p_copyto
		Erase me.p_blindcopyto
		me.NoReply = False	' Default is not to add a disclaimer to the end
	End Sub
	
	Private Sub CreateBody()
		Set me.body = New NotesRichTextItem(maildoc,"Body")
	End Sub
	
	Public Property Set Subject As String
		me.p_subject = FullTrim(Subject)
	End Property
	
	Public Property Get Subject As String
		Subject = me.p_subject
	End Property
	
	Public Property Set Principal As String
		me.p_principal = FullTrim(Principal)
	End Property
	
	Public Property Get Principal As String
		Principal = me.p_principal
	End Property

	'*** Recipient address (mailto) functions
	Public Property Set MailTo As String
		me.p_sendto(FullTrim(MailTo)) = FullTrim(MailTo)
	End Property
	
	Public Property Get MailTo As String	' Get the first address only
		ForAll mto In me.p_sendto
			MailTo = mto	
			Exit ForAll
		End ForAll
	End Property
	
	Public Property Set SendTo As String	' Alias for MailTo
		MailTo = SendTo
	End Property
	
	Public Property Get SendTo As String	' Alias for MailTo
		SendTo = MailTo	
	End Property
	
	Public Sub AddMailTo(address As String)	' Additional address
		me.p_sendto(address) = address
	End Sub
	
	Public Sub RemoveMailTo(address As String)	' Remove address from list
		Erase me.p_sendto(address)
	End Sub

	' *** Functions for CC address
	Public Property Set MailCC As String
		me.p_copyto(FullTrim(MailCC)) = FullTrim(MailCC)
	End Property
	
	Public Property Get MailCC As String	' Get the first address only
		ForAll mcc In me.p_copyto
			MailCC = mcc	
			Exit ForAll
		End ForAll
	End Property
	
	Public Sub AddMailCC(address As String)
		me.p_copyto(address) = address
	End Sub

	Public Sub RemoveMailCC(address As String)
		Erase me.p_copyto(address)
	End Sub
	
	' *** Functions for BCC address 
	Public Sub AddMailBCC(address As String)
		me.p_blindcopyto(address) = address
	End Sub
	
	Public Property Set MailBCC As String
		me.p_blindcopyto(FullTrim(MailBCC)) = FullTrim(MailBCC)
	End Property
	
	Public Property Get MailBCC As String	' Get the first address only
		ForAll bcc In me.p_blindcopyto
			MailBCC = bcc	
			Exit ForAll
		End ForAll
	End Property
	
	Public Sub RemoveMailBCC(address As String)
		Erase me.p_blindcopyto(address)
	End Sub
	
	' *** Functions for email body 
	Public Sub AppendText(bodytext As String)
		Call me.body.AppendText(bodytext)	
	End Sub
	
	Public Sub AppendDocLink(doc As NotesDocument, comment As String, linktext As String)
		If FullTrim(linktext) = "" Then
			Call me.body.AppendDocLink(doc, comment)	
		Else
			Call me.body.AppendDocLink(doc, comment, linktext)	
		End If
	End Sub
	
	Public Sub AppendNewLine(cnt As Integer)
		Call me.body.AddNewline(cnt)	
	End Sub
	
	Public Sub AddNewLine(cnt As Integer)
		Call me.body.AddNewline(cnt)	
	End Sub
	
	Public Sub AttachFile(filename As String)
		Call me.body.EmbedObject(1454,"",filename)	
	End Sub
	
	' *** Send the mail
	Public Sub Send()
		Dim session As New NotesSession 
		Dim richStyle As NotesRichTextStyle 
		Dim recipients As String 
		If me.subject<,>,"" Then
			maildoc.Subject = me.subject
		End If
		recipients = ""
		If ListItemCount(me.p_sendto)>,0 Then
			maildoc.SendTo = ListToArray(me.p_sendto)
			recipients = recipients + Join(ListToArray(me.p_sendto),"~") + "~"
		End If
		If ListItemCount(me.p_copyto)>,0 Then
			maildoc.CopyTo = ListToArray(me.p_copyto)
			recipients = recipients + Join(ListToArray(me.p_copyto),"~") + "~"
		End If
		If ListItemCount(me.p_blindcopyto)>,0 Then
			maildoc.BlindCopyTo = ListToArray(me.p_blindcopyto)
			recipients = recipients + Join(ListToArray(me.p_blindcopyto),"~") + "~"
		End If
		maildoc.Recipients = FullTrim(Split(recipients,"~")) 
		If me.p_principal<,>,"" Then
			Call maildoc.ReplaceItemValue("Principal", me.p_principal)
			' If principal is set, we want to fix so mail looks like
			' it is coming from that address, need to set these fields
			Call maildoc.ReplaceItemValue("From", me.p_principal)
			Call maildoc.ReplaceItemValue("Sender", me.p_principal)
			Call maildoc.ReplaceItemValue("ReplyTo", me.p_principal)
			Call maildoc.ReplaceItemValue("SMTPOriginator", me.p_principal)
		End If
		' If NoReply is set, append some red text... 
		If NoReply = True Then
			Set richStyle = session.CreateRichTextStyle
			richStyle.NotesFont = 4
			richStyle.NotesColor = 2
			richStyle.Bold = True	
			Call me.body.AppendStyle(richStyle)
			Call me.body.AddNewLine(1)	
			Call me.body.AppendText("*** DO NOT REPLY TO THE SENDER OF THIS MESSAGE! ***")	
			Call me.body.AddNewLine(1)	
			Call me.body.AppendText("*** IT IS AN AUTOMATED SYSTEM MAIL ***")	
		End If
		On Error Resume Next
		'Call maildoc.CopyItem(body, "Body")
		If me.p_principal<,>,"" Then
			Call maildoc.Save(True,False)	' Save in mail.box
		Else
			Call maildoc.Send(False)			' Send mail normally
		End If
	End Sub
	
	
	' *** Private functions called from within the class ***
	
	' *** Convert list to array
	Private Function ListToArray(textlist As Variant) As Variant
		Dim i As Integer 
		Dim temparray() As String
		ReDim temparray(0) As String 
		ForAll t In textlist
			temparray(UBound(temparray)) = t
			ReDim Preserve temparray(UBound(temparray)+1) As String
		End ForAll
		ListToArray = FullTrim(temparray)
	End Function
	
	' *** Count items in a list
	Private Function ListItemCount(textlist As Variant) As Integer
		Dim cnt As Integer
		cnt = 0
		ForAll t In textlist
			cnt = cnt + 1
		End ForAll
		ListItemCount = cnt
	End Function

End Class


%REM
	Class HTMLMail
	Description: Inherits from NotesMail class, implements additional functions
%END REM
Class HTMLMail As NotesMail
	Private session As NotesSession 
	Private mimebody As NotesMIMEEntity 
	Private header As NotesMIMEHeader 
	Private stream As NotesStream
	Private p_server As String
	Private p_protocol As String
	Private p_port As Integer
	Public LinkServerOnly As Boolean
		
	%REM
		Sub CreateBody
		Description: Override body creation with HTML body
	%END REM
	Private Sub CreateBody()
		Dim db As NotesDatabase 
		Set session = New NotesSession()
		Set db = session.CurrentDatabase 
		Set stream = session.CreateStream 
		session.ConvertMIME = False ' Do not convert MIME to rich text 
		Set me.mimebody = maildoc.CreateMIMEEntity
		Call stream.writetext(|<,HTML>,|)
		Call stream.writetext(|<,head>,|)
		Call stream.writetext(|<,/head>,|)
		Call stream.writetext(|<,body>,|)
		Call stream.writetext(|<,div style="font-family: Calibri,Arial; font-size:12pt;">,|)
		me.p_protocol = "notes"
		me.p_port = 80
		LinkServerOnly = False
	End Sub
	
	Public Sub AppendText(bodytext As String)
		Call me.stream.writetext(bodytext)	
	End Sub
	
	Public Sub AddNewLine(cnt As Integer)
		Dim i As Integer
		For i = 1 To cnt
			Call me.stream.writetext("<,br>,")
		Next 
	End Sub

	Public Sub AppendNewLine(cnt As Integer)
		Dim i As Integer
		For i = 1 To cnt
			Call me.stream.writetext("<,br>,")
		Next 
	End Sub

	Public Sub SetLinkServer(server As String)
		Me.p_server = server
	End Sub
	
	Public Sub SetLinkProtocol(protocol As String)
		Me.p_protocol = protocol
	End Sub

	Public Sub SetLinkPort(port As Integer)
		Me.p_port = port
	End Sub
	
	Public Sub AppendDocLink(doc As NotesDocument, comment As String, linktext As String)
		Dim html As String
		Dim link As Link
		Set link = New Link(doc)
		Call link.SetProtocol(Me.p_protocol)
		Call link.SetPort(Me.p_port)
		If Me.p_server<,>,"" Then
			Call link.SetServer(p_server)
		End If
		link.ServerOnly = LinkServerOnly
		html = |<,a href="| & link.URL() + |"|
		If FullTrim(linktext)<,>,"" Then
			html = html + | title="| + comment + |" alt="| + comment + |"|					
		End If
		html = html + ">," + linktext + "<,/a>,"
		Call AppendText(html)
	End Sub
	
	Sub AddNoReplyNotification()
		Call me.stream.writetext(|<,div style="font-family: consolas, courier; font-size: 10pt; color:#FF0000; margin-top: 25px; margin-bottom: 25px;">,|)
		Call me.stream.writetext("***************************************************<,br>,")	
		Call me.stream.writetext("*** DO NOT REPLY TO THE SENDER OF THIS MESSAGE! ***<,br>,")	
		Call me.stream.writetext("***   IT IS AN AUTOMATED SYSTEM MAIL FROM LNP   ***<,br>,")	
		Call me.stream.writetext("***************************************************<,br>,")
		Call me.stream.writetext("<,/div>,")
		If me.p_principal = "" Then
			me.p_principal = |"Do Not Reply" <,noreply@deep-south.com>,|
		End If
	End Sub
	
	' *** Send the mail
	Public Sub Send()
		Dim doc As NotesDocument 
		Dim recipients As String

		maildoc.Form = "Memo" 
		'*** If NoReply is set, append some red text... 
		If NoReply = True Then
		'	Call stream.writetext(|<,p>,<,font color="red">,|)
		'	Call stream.writetext("*** DO NOT REPLY TO THE SENDER OF THIS MESSAGE! ***<,br>,")	
		'	Call stream.writetext("*** IT IS AN AUTOMATED SYSTEM MAIL ***")
		'	Call stream.writetext("<,/font>,<,/p>,")
			Call AddNoReplyNotification()	
		End If
	 	'*** Add HTML for end of email
		Call stream.writetext(|<,/div>,|) 
		Call stream.writetext(|<,/body>,|) 
		Call stream.writetext(|<,/html>,|) 
		Call mimebody.SetContentFromText(stream, "text/HTML;charset=UTF-8", ENC_IDENTITY_7BIT) 
 
		If me.subject<,>,"" Then
			maildoc.Subject = me.subject
		End If
		recipients = ""
		If ListItemCount(me.p_sendto)>,0 Then
			maildoc.SendTo = ListToArray(me.p_sendto)
			recipients = recipients + Join(ListToArray(me.p_sendto),"~") + "~"
		End If
		If ListItemCount(me.p_copyto)>,0 Then
			maildoc.CopyTo = ListToArray(me.p_copyto)
			recipients = recipients + Join(ListToArray(me.p_copyto),"~") + "~"
		End If
		If ListItemCount(me.p_blindcopyto)>,0 Then
			maildoc.BlindCopyTo = ListToArray(me.p_blindcopyto)
			recipients = recipients + Join(ListToArray(me.p_blindcopyto),"~") + "~"
		End If
		maildoc.Recipients = FullTrim(Split(recipients,"~")) 
		If me.p_principal<,>,"" Then
			Call maildoc.ReplaceItemValue("Principal", me.p_principal)
			' If principal is set, we want to fix so mail looks like
			' it is coming from that address, need to set these fields
			Call maildoc.ReplaceItemValue("From", me.p_principal)
			Call maildoc.ReplaceItemValue("Sender", me.p_principal)
			Call maildoc.ReplaceItemValue("ReplyTo", me.p_principal)
			Call maildoc.ReplaceItemValue("SMTPOriginator", me.p_principal)
		End If
		On Error Resume Next
		If me.p_principal<,>,"" Then
			Call maildoc.Save(True,False)	' Save in mail.box
		Else
			Call maildoc.Send(False)			' Send mail normally
		End If
		session.ConvertMIME = True ' Restore conversion - very important 
	End Sub

End Class


%REM
	Class Link
	Description: Class for Doc Link functionality
%END REM
Class Link
	Private p_protocol As String
	Private p_server As String
	Private p_domain As String
	Private p_port As Integer
	Private p_dbpath As String
	Private p_docunid As String
	Private p_Action As String 
	Private p_doc As NotesDocument
	Private p_db As NotesDataBase
	Public ServerOnly As Boolean
	
	%REM
		Sub New
		Description: Constructor
	%END REM
	Public Sub New(doc As NotesDocument) 
		Dim server As NotesName
		Set p_doc = doc
		Set p_db = doc.Parentdatabase
		Set server = New NotesName(p_db.Server)
		Call SetServer(server.Common)
		Call SetPort(80)
		Call SetProtocol("notes") 	'Set as default
		ServerOnly = False
		p_domain = GetDomain()
		p_dbpath = doc.Parentdatabase.Filepath
		p_docunid = doc.UniversalID
		p_action = "OpenDocument"
	End Sub
	
	%REM
		Sub SetProtocol
		Description: Set the protocol to use (notes:, http:, https:)
	%END REM
	Public Sub SetProtocol(protocol As String)
		Dim tmp As String
		'*** Remove any : or /
		tmp = Replace(protocol,":","")
		tmp = Replace(tmp,"/","")
		p_protocol = LCase(tmp) + ":"
		If Not p_db Is Nothing Then
			tmp = GetDomain()
			Call SetDomain(tmp)
		End if
	End Sub
	
	%REM
		Sub SetAction
		Description: Set the action, e.g. ?OpenDocument
	%END REM
	Public Sub SetAction(action As String)
		Dim tmp As String
		'*** Remove any ? if already there
		tmp = Replace(action,"?","")
		p_action = "?" + tmp
	End Sub
	
	%REM
		Sub SetServer
		Description: Override server name if we want another server
		Do not specify the Notes domain or Internet domain name!
	%END REM
	Public Sub SetServer(servername)
		p_server = servername
	End Sub

	Public Function GetDomain() As String 
		Dim tmp As String
		Dim startpos As Integer
		Dim endpos As Integer  
		If p_protocol = "notes:" Then
			tmp = p_db.NotesURL
		Else
			tmp = p_db.HttpURL
		End If
		startpos = InStr(tmp,"://")+3
		endpos = InStr(startpos,tmp,"/")
		If endpos>,startpos Then
			tmp = Mid$(tmp,startpos, endpos-startpos)
		Else
			tmp = "deep-south.com"
		End If
		GetDomain = tmp
	End Function
	
	%REM
		Sub SetDomain
		Description:Set the domain part of the URL, e.g. @Deep-South or .deep-south.com 
	%END REM
	Public Sub SetDomain(domain As String)
		p_domain = domain
	End Sub
	
	%REM
		Sub SetPort
		Description: Set the port number, e.g. 80 or 3000
	%END REM
	Public Sub SetPort(portnumber As Integer)
		p_port = portnumber
	End Sub
	
	%REM
		Function URL
		Description: Get the URL for the document
	%END REM
	Public Function URL() As String
		Dim tmp As String 
		tmp = p_protocol & "//" 
		If p_protocol<,>,"notes:" Then
			tmp = tmp & p_server 
			If ServerOnly = False Then
				tmp = tmp & "."
			End if 
		End If
		If ServerOnly = False Then
			tmp = tmp & p_domain
		End If
		If p_protocol<,>,"notes:" Then
			If p_port <,>, 80 Then
				tmp = tmp & ":" & p_port  
			End If
		End If
		tmp = tmp & "/" & p_dbpath & "/0/" & p_docunid & "?" & p_action
		tmp = Replace(tmp,Chr$(92),"/")	'Replace \ with / for URL
		URL = tmp
	End Function
	
End Class

MWLUG in Austin – I will be presenting again

Posted on by Posted in Bootstrap, HTML/CSS, IBM/Lotus, jQuery, Lotusscript, MWLUG, Web Development Leave a comment

I have been selected to present at MWLUG in Austin on August 17-19. My presentation will be kind of part two of my presentation last year in Atlanta. It will focus less on the basics and go more into the fun and more advanced stuff. Kind of an extended version of my Connect 2016 presentation.

The title is “Think Outside The Box – Part 2”, and I will discuss and show how you can build a modern web front-end using standard techniques like Javascript/jQuery and frameworks like Bootstrap and jQuery Mobile and have it work against a Domino backend. I will demonstrate how to easily read data from and write data to the Domino database, and how to consume data using free plugins like BootstrapTable and FullCalendar.

I will also discuss the difference between JSON and JSONP and why the latter usually is better when building this type of integration. You will leave with a sample database containing the source code all the demos I will be showing as well as Lotusscript script libraries with classes I built to easily build agents that will interact with the website.

The idea is that you should be able to attend my session in Austin even if you haven’t seen any previous presentation. I will assume you have basic web design skills (HTML, CSS and a working understanding of Javascript) but you don’t have to be an expert at all. I also recommend some Lotusscript knowledge, as I will be providing all attendees with plenty of code to bring home and start using yourself.

I hope to see you in Austin in August! If you haven’t registered yet, go ahead and do it now! There are still seats left.

My Connect 2016 presentation & demo database

Posted on by Posted in Bootstrap, Community, Connect, HTML/CSS, IBM/Lotus, jQuery, Lotusscript, Notes/Domino, Web Development 6 Comments

Connect2016_DemoDesignAs I promised, I would post my IBM Connect 2016 presentation on my blog.

Presentation (PDF): {link} 

Demo database (ZIP): {link}

You can also find the presentation on SlideShare.net.

To the right you see the database design, you want to look in the Agent section for the agents and in the Pages section for the HTML pages.

Note: You need to sign the database with an ID that have the proper rights. Otherwise the code will not work.

Enjoy!

 

Free Code – Clean groups in Domino Directory

Posted on by Posted in Lotusscript, Programming 8 Comments

The other day I had to clean up the groups in our Domino Directory. Many groups still contained names of terminated users, they had not been cleaned/maintained properly. We also removed some groups over time, but some of them were still listed as members of other groups.

So I wrote a small Lotuscript agent to perform this cleanup. I am posting it below in case someone needs it. As always: no guarantees, use at your own risk, etc.

Update: As some commenters pointed out, there are some issues with the code. First of all, I was using a view my company added to name.nsf. The view PeopleByFirstName has the following selection formula: SELECT Type = “Person” & TerminationDate=””
The field TerminationDate is one we added to the person document. This field is either blank (for current employees) or contains the date they were terminated (and then they are filtered out of most views).

Also as Christian points out, any groups that contains external users would be clenaed out. In the past when I worked at a company that used mail groups with external users, those groups were kept in a separate (secondary) Domino Directory, names_ext.nsf. So this is something to keep in mind if you choose to use this code.

Finally I have updated the code with a few more lines. It will now ignore server groups, and also get a list of all servers and make sure they are included as group members when the groups are processed.

Thanks for pointing out the problems with the code!

 

Dim session As New NotesSession
Dim db As NotesDatabase
Dim view As NotesView
Dim doc As NotesDocument
Dim userNames List As String
Dim groupNames List As String
Dim serverNames List As String
Dim groups List As NotesDocument
Dim tmp As String
Dim tmpname As NotesName
	
Set db = New NotesDatabasesession.CurrentDatabase.Server,"names.nsf")
'*** Get all existing groups and put in a list
Set view = db.getView("Groups")
Set doc = view.GetFirstDocument()
Do Until doc Is Nothing
    Set groups(doc.UniversalID) = doc
    tmp = doc.GetItemValue("ListName")(0)
    groupNames(tmp) = tmp
    Set doc = view.GetNextDocument(doc)	
Loop

'*** Get all active users and put in a list
Set view = db.getView("PeopleByFirstName")
Set doc = view.GetFirstDocument()
Do Until doc Is Nothing
    tmp = doc.GetItemValue("FullName")(0)
    Set tmpname = New NotesName(tmp)
    userNames(tmpname.Common) = tmpname.Common
    Set doc = view.GetNextDocument(doc)	
Loop

'*** Get all servers and put in a list
Set view = db.getView("Servers")
Set doc = view.GetFirstDocument()
Do Until doc Is Nothing
    tmp = doc.GetItemValue("ServerName")(0)
    Set tmpname = New NotesName(tmp)
    serverNames(tmpsname.Common) = tmpname.Common
    Set doc = view.GetNextDocument(doc) 
Loop	
'*** Loop though list of groups and process each one
ForAll g In groups
    '*** Check that not server group
    If g.GetItemValue("GroupType")(0)<>"4" Then  
        tmp = ""
        '*** Store existing list of group members in a backup field
        Call g.ReplaceItemValue("MembersBackup",g.GetItemValue("Members")) 
        '*** Loop through all members of the group
        ForAll m In g.GetItemValue("Members")
            Set tmpname = New NotesName(m)
            '*** If the name is an existing group or an active user, add to list
            If IsElement(userNames(tmpname.Common)) _
            Or IsElement(groupNames(tmpname.Common)) _
            Or IsElement(serverNames(tmpname.Common))Then
                tmp = tmp + tmpname.Canonical + ";"
            End If
        End ForAll
        '*** Write list back to members field
        Call g.ReplaceItemValue("Members", FullTrim(Split(tmp,";")))
        Call g.Save(True,False)
    End If
End ForAll
MsgBox "Done!"

 

Calling a Notes web agent from another server using JSONP

Posted on by Posted in Javascript, jQuery, Lotusscript, Notes/Domino, Programming, Web Development Leave a comment

In my MWLUG presentation (as well as in a couple of entries on this blog) I talk about how you can access Domino data from a regular webpage using jQuery and a Lotusscript agent returning data as JSON. The issue with this solution is that the web page must be on the same web application path as the Domino agent. You can’t do what’s known as cross-domain Ajax.

For example if the Domino server is domino.texasswede.com but you have the webpage hosted at www.texasswede.com, it will not work. The security in Javascript does not allow calls across servers like that. There is however an easy solution, and it is called JSONP. What you do is to return not JSON but a call-back function with the JSON data as the argument.

So instead of returning this:

{ "firstName":"Karl-Henry", "lastname":"Martinsson","email":"texasswede@gmail.com" }

you would have the Lotuscript agent return this:

personCallBack({ "firstName":"Karl-Henry", "lastname":"Martinsson","email":"texasswede@gmail.com" })

Let’s assume we call the agent GetPersonData.jsonp.  On the calling side (in the jQuery code) you would then use this code:

$.ajax({
    url : "http://domino.texasswede.com/database.nsf/GetPersonData.jsonp?OpenAgent",
    dataType:"jsonp"
});

Finally you write the Javascript call-back function that will accept the data:

function personCallBack(data) {
    $("#firstName").html(data["firstName"]);
    $("#lastName").html(data["lastName"]);
    $("#emailAddress").html(data["email"]);
}

You can of course make this as advanced as you like but this is the basics. I have updated the JSON class I use for stuff like this to include a method to return JSONP. The new function is called SendJSONPToBrowser() and takes a string with the name of the call-back function as argument, for example like this:

Call json.SendJSONPToBrowser("personCallBack")

Below is the updated class (if you downloaded my sample database from MWLUG you have the older version of it). Enjoy!

 

%REM
	Library Class.JSON by Karl-Henry Martinsson
	Created Oct 9, 2014 - Initial version
	Updated Nov 6, 2015 - Added JSONP support
	Description: Class to generate simple JSON from values
%END REM

Option Public
Option Declare

Class JSONdata
	Private p_json List As String
	
	Public Sub New()
		'*** Set default value(s)
		me.p_json("ajaxstatus") = ""
	End Sub
	
	%REM
		Property Set success
		Description: Set success to true or false
	%END REM
	Public Property Set success As Boolean
		If me.success Then 
			Call me.SetValue("ajaxstatus","success")
		Else
			Call me.SetValue("ajaxstatus","error")
		End If
	End Property
	
	%REM
		Property Get success
		Description: Not really used...
	%END REM
	Public Property Get success As Boolean
		If me.p_json("ajaxstatus") = |"success"| Then
			me.success = True
		Else
			me.success = False
		End If
	End Property
	
	%REM
		Sub SetMsg
		Description: Set msg item
	%END REM
	Public Sub SetMsg(message As String)
		Call me.SetValue("msg",message)
	End Sub
	
	Public Sub SetErrorMsg(message As String)
		Call me.SetValue("errormsg",message)
		me.success = False
	End Sub
	
	Public Sub SetValue(itemname As String, value As String)
		Dim tmp As String
		Dim delimiter As String
		'*** Check for quote (double and single) and fix value if needed
		tmp = Replace(value,Chr$(13),"<br>")
		tmp = FullTrim(Replace(tmp,Chr$(10),""))
		If InStr(tmp,|"|)>0 Then
			If InStr(tmp,|'|)>0 Then
				tmp = Replace(tmp,|"|,|"|)
				delimiter = |"|
			Else
				delimiter = |'|
			End If
		Else
			delimiter = |"|
		End If
		'*** Store value with delimiter in list
		me.p_json(itemname) = delimiter & tmp & delimiter
	End Sub
	
	Public Sub SetData(itemname As String, value As String)
		'*** Store value in list
		me.p_json(itemname) = value
	End Sub
	
	%REM
		Function GetJSON
		Description: Return a JSON object as text
	%END REM
	Function GetJSON As String
		Dim json As String
		'*** Opening curly braces + CR
		json = "{" + Chr$(13)
		'*** Loop through all list elements and build JSON
		ForAll j In me.p_json
			json = json + |"| + ListTag(j) + |":| + j + "," + Chr$(13)
		End ForAll
		'*** Remove the comma after the last item
		json = Left$(json,Len(json)-2) + Chr$(13)
		'*** Add closing curly bracket and return JSON
		json = json + "}"
		GetJSON = json 
	End Function
	
	%REM
		Sub SendToBrowser
		Description: Print JSON to browser, with correct MIME type
	%END REM
	Public Sub SendToBrowser()
		'*** MIME Header to tell browser what kind of data we will return (JSON).
		'*** See http://www.ietf.org/rfc/rfc4627.txt
		Print "content-type: application/json"
		Print me.GetJSON
	End Sub
	
	%REM
		Sub SendJSONPToBrowser
		Description: Print JSON to browser, with correct MIME type
	%END REM
	Public Sub SendJSONPToBrowser(callbackFunction As String)
		'*** MIME Header to tell browser what kind of data we will return (Javascript).
		'*** See http://www.rfc-editor.org/rfc/rfc4329.txt
		Print "content-type: application/javascript"
		Print callbackFunction + "(" + me.GetJSON + ")"
	End Sub
	
End Class

 

MWLUG in Atlanta – I will be presenting!

Posted on by Posted in Bootstrap, Community, IBM/Lotus, jQuery, Lotusscript, MWLUG, Web Development 1 Comment

It is less than 7 weeks left until MWLUG, the Midwest Lotus User Group conference. This year the conference takes place in Atlanta, between August 19 and 21. During the three days there will be over 40 technical session and workshops on collaboration, receptions and networking opportunities, as well as access to experts of IBM solutions, both from IBM and other companies. The topics includes application development, system administration, best practices, customer buisness cases and innovation/future plans by IBM. Breakfast and lunch is included for two days as well. And all this for the cost of only $50 per person! The event takes place at Ritz-Carlton in downtown Atlanta. There is a block of rooms reserved at a special conference rate of $149.00 per night.

One of the sessions will also mark my personal debute as a speaker at a conference. I will present “Break out of the box – Integrate existing Domino data with modern websites” where I will talk about how to integrate websites built either within Domino or on other platforms with backend data that resides in a Domino database. I will talk about how you can build a modern looking website using tools like jQuery and Bootstrap and seamlessly integrate them with existing data on your trusty Domino server using JSON and Ajax. I will also provide plenty of example code ready for you to bring home and start playing with.

A number of IBM Champions will be presenting, as well as IBMers and other industry experts. So no matter your interest, I am sure you will find plenty of good sessions. I am sure I will have a hard time picking which sessions to attend!

So what are you waiting for? Go to http://www.mwlug.com and register! See you there!