Category Archives: Programming

A question was posted in the IBM DeveloperWorks forum for Notes/Domino 8 about the possibility to detect from within Notes if a computer is equipped with a touch screen. The answer was that you have to check if a specific DLL is installed, which is done though the registry.

The original posted then asked how to do that in Lotusscript, so I deceded to simply post some code I am using. I did not write this code, and I don’t know who originally did. I think I may have taken some VB code and simply adapted it for Lotusscript. I plan to rewrite this a s a class when I have some time. In the mean time, here is the code.

Option Public
Option Declare

Dim REG_NONE As Long 
Dim REG_SZ As Long 
Dim REG_EXPAND_SZ As Long
Dim REG_BINARY As Long 
Dim REG_DWORD As Long 
Dim REG_DWORD_LITTLE_ENDIAN As Long
Dim REG_DWORD_BIG_ENDIAN As Long
Dim REG_LINK As Long
Dim REG_MULTI_SZ As Long
Dim REG_RESOURCE_LIST As Long
Dim REG_FULL_RESOURCE_DESCRIPTOR As Long

Declare Function RegCloseKey Lib "advapi32.dll" (Byval hKey As Long) As Long

Declare Function RegCreateKeyEx Lib "advapi32.dll" Alias "RegCreateKeyExA" (Byval hKey As Long, _
Byval lpSubKey As String, Byval Reserved As Long, Byval lpClass As String, _
Byval dwOptions As Long, Byval samDesired As Long, Byval lpSecurityAttributes As Long, _
phkResult As Long, lpdwDisposition As Long) As Long

Declare Function RegOpenKeyEx Lib "advapi32.dll" Alias "RegOpenKeyExA" (Byval hKey As Long, _
Byval lpSubKey As String, Byval ulOptions As Long, Byval samDesired As Long, _
phkResult As Long) As Long

Declare Function RegSetValueExString Lib "advapi32.dll" Alias "RegSetValueExA" (Byval hKey As Long, _
Byval lpValueName As String, Byval Reserved As Long, Byval dwType As Long, Byval lpValue As String, _
 Byval cbData As Long) As Long

Declare Function RegSetValueExLong Lib "advapi32.dll" Alias "RegSetValueExA" (Byval hKey As Long, _
Byval lpValueName As String, Byval Reserved As Long, Byval dwType As Long, lpValue As Long, _
Byval cbData As Long) As Long 

Declare Function RegQueryValueExString Lib "advapi32.dll" Alias "RegQueryValueExA" _
(Byval hKey As Long, Byval lpValueName As String, Byval lpReserved As Long, lpType As Long, _
Byval lpData As String, lpcbData As Long) As Long

Declare Function RegQueryValueExLong Lib "advapi32.dll" Alias "RegQueryValueExA" _
(Byval hKey As Long, Byval lpValueName As String, Byval lpReserved As Long, lpType As Long, _
lpData As Long, lpcbData As Long) As Long

Declare Function RegQueryValueExNULL Lib "advapi32.dll" Alias "RegQueryValueExA" _
(Byval hKey As Long, Byval lpValueName As String, Byval lpReserved As Long, lpType As Long, _
Byval lpData As Long, lpcbData As Long) As Long

' --- Registry key values
Const HKEY_CLASSES_ROOT = &H80000000
Const HKEY_CURRENT_USER = &H80000001
Const HKEY_LOCAL_MACHINE = &H80000002
Const HKEY_USERS = &H80000003
Const HKEY_CURRENT_CONFIG = &H80000005

' --- Registry return values
Const ERROR_NONE = 0
Const ERROR_BADDB = 1
Const ERROR_BADKEY = 2
Const ERROR_CANTOPEN = 3
Const ERROR_CANTREAD = 4
Const ERROR_CANTWRITE = 5
Const ERROR_OUTOFMEMORY = 6
Const ERROR_INVALID_PARAMETER = 7
Const ERROR_ACCESS_DENIED = 8
Const ERROR_INVALID_PARAMETERS = 87
Const ERROR_NO_MORE_ITEMS = 259

' --- Registry access key
Const KEY_ALL_ACCESS = &H3F
Const REG_OPTION_NON_VOLATILE = 0


Sub Initialize
	REG_NONE = 0
	REG_SZ  = 1
	REG_EXPAND_SZ = 2
	REG_BINARY = 3
	REG_DWORD = 4
	REG_DWORD_LITTLE_ENDIAN = 4
	REG_DWORD_BIG_ENDIAN = 5
	REG_LINK = 6
	REG_MULTI_SZ = 7
	REG_RESOURCE_LIST = 8
	REG_FULL_RESOURCE_DESCRIPTOR = 9
End Sub


Function SetValueEx(Byval lngHKey As Long, strValueName As String, lngType As Long, varValue As Variant) As Long
	Dim lngValue As Long
	Dim strValue As String
	
	Select Case lngType
	Case REG_SZ
		strValue = varValue & Chr(0)
		SetValueEx = RegSetValueExString(lngHKey, _
		strValueName, _
		0&, _
		lngType, _
		strValue, _
		Len(strValue))
	Case REG_DWORD
		lngValue = varValue
		SetValueEx = RegSetValueExLong(lngHKey, _
		strValueName, _
		0&, _
		lngType, _
		lngValue, _
		4)
	End Select
End Function


Sub RegistryCreateKey(dblHiveID As Double, strBaseKey As String, strKey As String, strData As String)
	Dim lngResult As Long
	Dim lngDisplay As Long
	Dim intReturn As Integer
	
	lngResult = 0
	lngDisplay = 0
	intReturn = RegCreateKeyEx(Byval dblHiveID, _
	Byval strBaseKey, _
	Byval 0&, _
	Byval "REG_SZ", _
	Byval 0&, _
	Byval KEY_ALL_ACCESS, _
	Byval 0&, _
	lngResult, _
	lngDisplay)
	intReturn = RegSetValueExString(Byval lngResult, _
	Byval strKey, _
	Byval 0&, _
	Byval 1&, _
	Byval strData, _
	Byval Len(strData))
End Sub 


Function RegistryGetValue(dblHiveID As Double, strKeyName As String, strValueName As String, _
strDefaultValue As Variant) As Variant
	Dim lngReturn As Long    ' result of the API functions
	Dim lngHKey As Long      ' handle of opened key
	Dim varValue As Variant  ' setting of queried value
	
	On Error Goto RegistryGetValueError
	lngReturn = RegOpenKeyEx(dblHiveID, strKeyName, 0, _
	KEY_ALL_ACCESS, lngHKey)
	lngReturn = RegistryQueryValueEx(lngHKey, strValueName, varValue)
	RegCloseKey (lngHKey)
	If (varValue = "") Then
		RegistryGetValue = strDefaultValue
	Else
		RegistryGetValue = varValue
	End If
	Exit Function
RegistryGetValueError:
	RegistryGetValue = strDefaultValue
End Function


Function RegistryQueryValueEx(Byval lngHKey As Long, Byval strValueName As String, _
varValue As Variant) As Long
	Dim lngDataPntr As Long
	Dim lngReturn As Long
	Dim lngType As Long
	Dim lngValue As Long
	Dim strValue As String
	
	On Error Goto RegistryQueryValueExError
    ' Determine the size and type of data to be read
	lngReturn = RegQueryValueExNULL(lngHKey, strValueName, 0&, _
	lngType, 0&, lngDataPntr)
	If (lngReturn <> ERROR_NONE) Then
		Error 5
	End If
	Select Case lngType
        ' For strings
		Case REG_SZ:
			strValue = String(lngDataPntr, 0)
			lngReturn = RegQueryValueExString(lngHKey, _
			strValueName, 0&, _
			lngType, strValue, lngDataPntr)
			If (lngReturn = ERROR_NONE) Then
				varValue = Trim(Left(strValue, lngDataPntr - 1))
			Else
				varValue = FullTrim("")		'returns empty
			End If
   	     ' For DWORDS
		Case REG_DWORD:
			lngReturn = RegQueryValueExLong(lngHKey, _
			strValueName, 0&, _
			lngType, lngValue, lngDataPntr)
			If (lngReturn = ERROR_NONE) Then
				varValue = lngValue
			End If
		Case Else
            ' all other data types not supported
			lngReturn = -1
	End Select
RegistryQueryValueExExit:
	RegistryQueryValueEx = lngReturn
	Exit Function
RegistryQueryValueExError:
	Resume RegistryQueryValueExExit
End Function

Yesterday I was asked to create a way to let us disable agents running on a Domino server in an easy way before the Domino server comes back from a crash.

The reason for this request is that for a while we have been having one particular agent crash, taking the whole Domino server down with it. It only happens occasionally, and seems to be related to the document being processed. When the server comes up after a crash like that, a consistence check is done, then the agent manager launches the agent again, causing the server to go down again. I added code to the offending agent, so it would flag the document before processing and un-flag after processing is done. This way, when the agent encounters an already flagged document, it will be skipped as it was processed during a previous crash.

For some reason this did not work yesterday morning, when one of those rare corrupted(?) documents was encountered. The logic in the code was faulty, because the document was of a new type, so it was never flagged as being processed. The same document was processed over and over again, taking the server down every time.

So I simply created two functions, put them in a global script library where I keep utility functions used in many places, and added 3 lines of code to each agent where I wanted this functionality.

The first function is simply to check if a specified file exists. I am using en error handler to catch any error (for example missing directory).

Function FileExists(filename As String) As Boolean
    On Error GoTo errHandler
    If Dir$(filename)<>"" Then
        FileExists = True
    Else
        FileExists = False
    End If
exitFunction:
    Exit Function
errhandler:
    FileExists = False
    Resume exitFunction
End Function

The second function is the one where I check for the existance of a file named the same as the agent, with an extension of .disabled. If that file does not exist, I check for a file with the extension .enabled. If that file is missing, I simply create a blank file with that name. This way, the first time any agent is executed, the file will be created for us, and I don’t have to sit and manually create them all.

Function DisableAgent() As Boolean
    Dim session As New NotesSession
    Dim agentname As String
    Dim filename As String 

    agentname = session.CurrentAgent.Name
    filename = "D:\NotesAgentControlFiles\" + agentname + ".disabled"
    If FileExists(filename) Then
        DisableAgent= True
    Else
        filename = "D:\NotesAgentControlFiles\" + agentname + ".enabled"
        If Not FileExists(filename) Then	
            Open filename For Output As #1
            Print #1, ""
            Close #1
            Print "Created control file " & filename
        End If
        DisableAgent= False
    End If
End Function

Finally, in each agent I want to be able to disable like this, I add this code in the beginning:

'*** Check if disable-file exists, exit in that case
If DisableAgent() Then
    Exit Sub
End If

Just a few lines of code, but hopefully it will save someone a few minutes of work. Of course, you ca use this technique for many other things, your imagination is the limit.