TexasSwede
texasswede@gmail.com
  • About this blog
  • My Website
  • My Resume
  • XML Export Tool
  • Photos

Moving blog posts from Connections to WordPress

Posted on October 15, 2012 by Karl-Henry Martinsson Posted in Blogging, Lotusscript, Programming 1 Comment

As I switched from IBM Connection to WordPress for my blog, I started thinking about my existing content. Was there a way to move them all over without having to manually copy and paste and recreate all 268 entries?

Well, there is, and this is how I did it, using just a  few tools. First I used Wget to retrieve my old blog. This put all the posts on one folder (entries), and all images in another (resource). It was then a simple task to write a Lotusscript agent that processed each file in that folder and read the content, parsed out the title, date originally posted and HTML for the blog post itself. I put that data into separate Notes documents, after performing some cleanup and string replacement.

I had already moved all images to a filer on my primary web server, so I performed a replace of the image URLs in the HTML, to have any images pointing to their new location. I also had to fix some special characters and replace them with the corresponding HTML entities.

Now when I had all the data, I just wrote another agent to export the data out again, to create a CSV file. I then installed a CSV importer in my WordPress blog and used to to import the file I just created.

After a few tweaks I performed a successful import. Later I realized I had missed a few special characters, so I had to fix those entries, but we are talking about 4 or 5, out of 268 entries.

If there is an interest, I might clean up the code a little and create a nicer UI (right now many of the values like path and URL are hard-coded) and then release the code if anyone else is planning to go through the same exercise. Below is the existing code to read the blog entries into a simple Notes database.

Option Public
Option Declare

Dim entrydir As String
Dim resourcedir As String

Sub Initialize
	Dim filename As String
	Dim cnt List As Integer
	Dim blogentry List As String
	Dim tst As Variant 

	entrydir = "D:\BleedYellowBlog\www.bleedyellow.com\blogs\texasswede\entry\"
	resourcedir = "D:\BleedYellowBlog\www.bleedyellow.com\blogs\texasswede\resource\"

	cnt("Total") = 0
	filename = Dir$(entrydir + "*.*")
	Do While fileName <> ""
		blogentry(filename) = entrydir + filename
		cnt("Total") = cnt("Total") + 1
		fileName = Dir$()
	Loop

	cnt("Processed") = 0 
	ForAll be In blogentry 
		cnt("Processed") = cnt("Processed") + 1
		Print "Processing " & cnt("Processed") & " of " & cnt("Total")  
		Call ProcessBlogEntry(ListTag(be),be)	
	End ForAll
End Sub

Function FixHTML(html As String) As String
	Dim tmp As String

	tmp = Replace(html,_
"https://www.bleedyellow.com/blogs/texasswede/resource/",_
"http://www.texasswede.com/blogfiles/resource/")
	tmp = Replace(tmp,_
"http://www.bleedyellow.com/blogs/texasswede/resource/",_
"http://www.texasswede.com/blogfiles/resource/")
	tmp = Replace(tmp,"/BLOGS_UPLOADED_IMAGES/","/uploaded_images/")
	tmp = Replace(tmp,"´",|"&acute;"|)
	tmp = Replace(tmp,"’","&acute;")
	tmp = Replace(tmp,"“",|&quot;|)
	tmp = Replace(tmp,"”",|&quot;|)
	tmp = Replace(tmp,"…",|"..."|)
	tmp = Replace(tmp,"<wbr>",||)
	tmp = Replace(tmp,"> < ",|>&anp;nbsp;< |) 	
        FixHTML = tmp 
End Function 

Function ProcessBlogEntry(filename As String, localpath As String) As Boolean 	
        Dim session As New NotesSession 
	Dim db As NotesDatabase
        Dim blogentry As NotesDocument 	
        Dim rtitem As NotesRichTextItem
        Dim siteurl As String  	
        Dim html List As String
        Dim tmp As String
        Dim import As Boolean
        Dim titlesection As Boolean
        Dim row As Integer
        Dim currow As Integer  	
        Dim titletext As string
        Dim htmltext As String
        Dim title As String
        Dim posteddate As String
        import = False 	
        titlesection = False
        row = 0 	
        Open localpath For Input As #1 charset="UTF-8"
        Do Until EOF(1)
            Line Input #1, tmp
            If InStr(tmp,|class="entryContentContainer"|) > 0 Then
	 	import = True		
	    End If
	    If import = True Then
		If InStr(LCase(tmp),|<!-- rating -->|) > 0 Then
			import = False		
		End If
 	    End If
	    If InStr(LCase(tmp),|<!-- entry title and info -->|) > 0 Then
		titlesection = True		
	    End If
	    If titlesection = True Then
		If InStr(LCase(tmp),|<!-- user name, date, meta info -->|) > 0 Then
			titlesection = False
		End If
	    End If
	    If titlesection = True Then
		titletext = titletext + tmp
	    End If
	    If InStr(LCase(tmp),|blogsdate.date.localize|) > 0 Then
		posteddate = StrLeft(StrRight(tmp,"localize ("),"));")
	    End If
	    If import = True Then
		row = row + 1
	 	html(CStr(row)) = tmp
	    End If
	Loop
	Close #1

	Set db = session.CurrentDatabase 
	Set blogentry = New NotesDocument(db)
	blogentry.Form = "Blog Entry"
	title = Replace(FullTrim(StrLeft(StrRight(titletext,"<h4>"),"</h4>")),"@amp;quot;",|"|)
	Set rtitem = New NotesRichTextItem(blogentry,"Content") 
	posteddate = Format$(JSMillisecondsToLSDate(CDbl(posteddate)),"mm/dd/yyyy hh:nn") + " GMT"
	siteurl = "http://www.bleedyellow.com/blogs/texasswede/"

	Call blogentry.ReplaceItemValue("Title", title)
	Call blogentry.ReplaceItemvalue("PostedDate", posteddate)
	Call blogentry.ReplaceItemValue("OriginalURL", siteurl + filename)
	currow = 0
	ForAll t In html
		currow = currow + 1
		If InStr(t,	|class="entryContentContainer"|)>0 Then
			' Do nothing				
		Else
			If currow < row-2 Then
				Call rtitem.AppendText(fixhtml(t))
				Call rtitem.AddNewLine(1,true)
			End If
		End If
	End ForAll
	Call blogentry.ComputeWithForm(True,False)
	Call blogentry.Save(True,True)

End Function

Function JSMillisecondsToLSDate(millis As Double) As Variant
	Dim ndt As NotesDateTime
	Dim zoneOffset As Integer
	Dim jsEpochDouble As Double, adjustedEpochDouble As Double, millisDateDouble As Double

	%REM
	JavaScript millisecond values are based on GMT
	but writable LotusScript date/time values are local.
	We need to know the local timezone offset from GMT,
	and for that we need a NotesDateTime object
	with both date and time components
	%END REM

	Set ndt = New NotesDateTime(Now)
	zoneOffset = ndt.TimeZone

	'The JavaScript epoch is midnight (day start) January 1, 1970 GMT
	jsEpochDouble = CDbl(DateNumber(1970,1,1))

	'Adjust epoch to local time
	adjustedEpochDouble = jsEpochDouble - (zoneOffset/24)

	'There are 86400000 milliseconds in a day
	millisDateDouble = adjustedEpochDouble + (millis / 86400000)
	JSMillisecondsToLSDate = CDat(millisDateDouble)
End Function

 

And here is the  agent to export the documents to a CSV file that can be imported into a WordPress blog using the CSV import plugin.

Option Public
Option Declare

Sub Initialize
	Dim session As New NotesSession
	Dim db As NotesDatabase
	Dim view As NotesView
	Dim doc As NotesDocument
	Dim filename As String

	filename = "d:\bleedyellow.csv"
	Open filename For Output As #1
	Print #1, |"csv_post_title","csv_post_post",| + _ 
                  |"csv_post_type","csv_post_excerpt",| + _ 
                  |"csv_post_categories","csv_post_tags",| + _ 
                  |"csv_post_date","custom_field_1","custom_field_2"|
	Set db = session.Currentdatabase
	Set view = db.GetView("By Title")
	Set doc = view.GetFirstDocument
	Do Until doc Is Nothing
		Print #1, GetCSV(doc)
		Set doc = view.GetNextDocument(doc)	
	Loop
	Close #1
End Sub

Function GetCSV(doc As NotesDocument) As String
	Dim rtitem As NotesRichTextItem 
	Dim tmp As String
	Dim content As String

	Set rtitem = doc.Getfirstitem("Content")
	content = Replace(FullTrim(rtitem.GetUnformattedText()),|"|,|""|)
	tmp = |"| + Replace(doc.GetItemValue("Title")(0),|"|,|""|) + |",|
	tmp = tmp + |"| + content + |",|
	tmp = tmp + ",,"
	tmp = tmp +|"| + "Old Blog Post" + |",|
	tmp = tmp +|"| + doc.GetItemValue("Tags")(0) + |",|
	tmp = tmp +|"| + doc.GetItemValue("PostedDate")(0) + |",,,|

	GetCSV = tmp
End Function
« Welcome to my new blog
Fort Worth Airshow 2012 »

One thought on “Moving blog posts from Connections to WordPress”

  1. Eric Mack says:
    October 16, 2012 at 10:56

    Thanks for the post and for sharing the code. his will come in handy.

    Eric

    Reply

Leave a comment Cancel reply

Your email address will not be published. Required fields are marked *

This site uses Akismet to reduce spam. Learn how your comment data is processed.

Stack Exchange

profile for Karl-Henry Martinsson on Stack Exchange, a network of free, community-driven Q&A sites

Recent Posts

  • Domino 14 is now available
  • Domino 14 Early Access Program
  • Announced: Engage 2024
  • Integrate Node-RED with Notes and Domino
  • Notes and Domino v12 is here!

Recent Comments

  • Theo Heselmans on Announced: Engage 2024
  • Lotus Script Multi-thread Message Box [SOLVED] – Wanted Solution on ProgressBar class for Lotusscript
  • Viet Nguyen on Keep up with COVID-19 though Domino!
  • Viet Nguyen on Keep up with COVID-19 though Domino!
  • Mark Sullivan on Looking for a HP calculator? Look no further!

My Pages

  • How to write better code in Notes

Archives

  • December 2023 (1)
  • October 2023 (2)
  • September 2023 (1)
  • June 2021 (1)
  • April 2021 (2)
  • March 2021 (1)
  • August 2020 (3)
  • July 2020 (2)
  • April 2020 (2)
  • March 2020 (1)
  • December 2019 (2)
  • September 2019 (1)
  • August 2019 (2)
  • July 2019 (2)
  • June 2019 (3)
  • April 2019 (2)
  • December 2018 (1)
  • November 2018 (1)
  • October 2018 (5)
  • August 2018 (2)
  • July 2018 (3)
  • June 2018 (2)
  • May 2018 (1)
  • April 2018 (2)
  • March 2018 (1)
  • February 2018 (2)
  • January 2018 (4)
  • December 2017 (3)
  • November 2017 (2)
  • October 2017 (2)
  • September 2017 (1)
  • August 2017 (2)
  • July 2017 (6)
  • May 2017 (4)
  • February 2017 (1)
  • January 2017 (2)
  • December 2016 (2)
  • October 2016 (3)
  • September 2016 (4)
  • August 2016 (1)
  • July 2016 (2)
  • June 2016 (2)
  • May 2016 (3)
  • April 2016 (1)
  • March 2016 (4)
  • February 2016 (2)
  • January 2016 (4)
  • December 2015 (3)
  • November 2015 (2)
  • October 2015 (1)
  • September 2015 (2)
  • August 2015 (1)
  • July 2015 (5)
  • June 2015 (2)
  • April 2015 (2)
  • March 2015 (3)
  • February 2015 (2)
  • January 2015 (10)
  • December 2014 (1)
  • November 2014 (3)
  • October 2014 (3)
  • September 2014 (13)
  • August 2014 (6)
  • July 2014 (5)
  • May 2014 (3)
  • March 2014 (2)
  • January 2014 (10)
  • December 2013 (5)
  • November 2013 (2)
  • October 2013 (5)
  • September 2013 (4)
  • August 2013 (7)
  • July 2013 (3)
  • June 2013 (1)
  • May 2013 (4)
  • April 2013 (7)
  • March 2013 (8)
  • February 2013 (9)
  • January 2013 (5)
  • December 2012 (7)
  • November 2012 (13)
  • October 2012 (10)
  • September 2012 (2)
  • August 2012 (1)
  • July 2012 (1)
  • June 2012 (3)
  • May 2012 (11)
  • April 2012 (3)
  • March 2012 (2)
  • February 2012 (5)
  • January 2012 (14)
  • December 2011 (4)
  • November 2011 (7)
  • October 2011 (8)
  • August 2011 (4)
  • July 2011 (1)
  • June 2011 (2)
  • May 2011 (4)
  • April 2011 (4)
  • March 2011 (7)
  • February 2011 (5)
  • January 2011 (17)
  • December 2010 (9)
  • November 2010 (21)
  • October 2010 (4)
  • September 2010 (2)
  • July 2010 (3)
  • June 2010 (2)
  • May 2010 (3)
  • April 2010 (8)
  • March 2010 (3)
  • January 2010 (5)
  • November 2009 (4)
  • October 2009 (7)
  • September 2009 (1)
  • August 2009 (7)
  • July 2009 (1)
  • June 2009 (4)
  • May 2009 (1)
  • April 2009 (1)
  • February 2009 (1)
  • January 2009 (3)
  • December 2008 (1)
  • November 2008 (1)
  • October 2008 (7)
  • September 2008 (7)
  • August 2008 (6)
  • July 2008 (5)
  • June 2008 (2)
  • May 2008 (5)
  • April 2008 (4)
  • March 2008 (11)
  • February 2008 (10)
  • January 2008 (8)

Categories

  • AppDev (10)
  • Blogging (11)
    • WordPress (5)
  • Design (5)
    • Graphics (1)
    • UI/UX (2)
  • Featured (5)
  • Financial (2)
  • Food (5)
    • Baking (3)
    • Cooking (3)
  • Generic (11)
  • History (5)
  • Hobbies (10)
    • LEGO (4)
    • Photography (4)
  • Humor (1)
  • IBM/Lotus (178)
    • #Domino2025 (14)
    • #DominoForever (8)
    • #IBMChampion (46)
    • Administration (7)
    • Cloud (7)
    • CollabSphere (9)
    • Community (49)
    • Connect (33)
    • ConnectED (12)
    • Connections (3)
    • HCL (15)
    • HCL Master (1)
    • IBM Think (1)
    • Lotusphere (46)
    • MWLUG (25)
    • Notes/Domino (99)
      • Domino 11 (7)
    • Sametime (8)
    • Verse (14)
    • Volt (3)
    • Watson (6)
  • Life (8)
  • Microsoft (7)
    • .NET (2)
    • C# (1)
    • Visual Studio (1)
  • Movies (3)
  • Old Blog Post (259)
  • Personal (23)
  • Programming (84)
    • App Modernization (11)
    • Formula (4)
    • Lotusscript (47)
    • NetSuite (4)
      • SuiteScript (3)
    • node.js (4)
    • XPages (4)
  • Reviews (9)
  • Sci-Fi (4)
  • Software (24)
    • Flight Simulator (2)
    • Games (4)
    • Open Source (2)
    • Utilities (6)
  • Technology (37)
    • Aviation (3)
    • Calculators (2)
    • Computers (6)
    • Gadgets (7)
    • Mobile Phones (7)
    • Science (3)
    • Tablets (2)
  • Travel (7)
    • Europe (1)
    • Texas (2)
    • United States (1)
  • Uncategorized (16)
  • Web Development (50)
    • Frameworks (23)
      • Bootstrap (14)
    • HTML/CSS (12)
    • Javascript (32)
      • jQuery (23)

Administration

  • Log in
  • Entries feed
  • Comments feed
  • WordPress.org

Tracking

Creeper
MediaCreeper
  • Family Pictures
© TexasSwede 2008-2014